commit 08f7038475945f855f298864dea9ab242057c0bf
Author: Nicolas MASSE <nicolas.masse@itix.fr>
Date:   Sun Feb 24 15:17:49 2019 +0100

    first commit

diff --git a/cleanup-timemachine b/cleanup-timemachine
new file mode 100755
index 0000000..076d69e
--- /dev/null
+++ b/cleanup-timemachine
@@ -0,0 +1,106 @@
+#!/usr/bin/perl -w
+
+use Getopt::Long;
+use Pod::Usage;
+use File::Path qw/remove_tree/;
+
+use strict;
+
+sub filter_timestamps {
+  my @timestamps = @_;
+  my %timestamps;
+  my %slices;
+  my @n = (7, 5, 5);
+  @timestamps = sort @timestamps;
+  while (my $thing = pop @timestamps) {
+    my $slice1m = substr $thing, 0, 7;
+    my $slice10d = substr $thing, 0, 9;
+    # Keep the last 7 backups
+    if ($n[0]) {
+      $timestamps{$thing} = 1;
+      $n[0]--;
+      $slices{$slice10d}++;
+      $slices{$slice1m}++;
+      next;
+    } elsif ($n[1]) {
+      # Keep 1 backup for every 10 days (and at most 5 backups)
+      $slices{$slice10d}++;
+      $slices{$slice1m}++;
+      if ($slices{$slice10d} == 1) {
+        $timestamps{$thing} = 1;
+        $n[1]--;
+        next;
+      }
+    } elsif ($n[2]) {
+      # Keep 1 backup for every month (and at most 5 backups)
+      $slices{$slice1m}++;
+      if ($slices{$slice1m} == 1 and not $slices{$slice10d}) {
+        $timestamps{$thing} = 1;
+        $n[2]--;
+        next;
+      }
+    }
+    # else: discard the backup
+    $timestamps{$thing} = 0;
+  }
+  return %timestamps;
+}
+
+my $verbose;
+my $pretend;
+my $help;
+GetOptions("help|?"   => \$help,
+           "pretend"  => \$pretend,
+           "verbose"  => \$verbose)
+  or pod2usage(1);
+pod2usage(0) if $help;
+
+my @timestamps;
+my $tmdir = $ENV{HOME} . "/timemachine";
+opendir DH, $tmdir || die "opendir: $tmdir: $!";
+while (readdir DH) {
+  next if m/^\./;
+  next if ! m/^[0-9]{4}-[0-9]{2}-[0-9]{2} [0-9]{2}.[0-9]{2}.[0-9]{2}$/;
+  push @timestamps, $_;
+}
+closedir DH;
+
+my %timestamps = filter_timestamps(@timestamps);
+if ($verbose) {
+  print "Would remove "
+    . (scalar grep { ! $timestamps{$_} } keys %timestamps )
+    . " items\n";
+  print "Would keep "
+    . (scalar grep { $timestamps{$_} } keys %timestamps )
+    . " items\n";
+}
+
+while (my ($timestamp, $keep) = each(%timestamps)) {
+  next if $keep;
+  if ($pretend) {
+    print "rm -rf '$tmdir/$timestamp'\n";
+  } else {
+    remove_tree("$tmdir/$timestamp", {error => \my $err});
+    if (@$err) {
+      print "remove_tree: $timestamp: cannot remove specified folder !\n"
+        if $verbose;
+    }
+  }
+}
+
+__END__
+
+=head1 NAME
+
+cleanup-timemachine - Cleans the timemachine folder
+
+=head1 SYNOPSIS
+
+C<cleanup-timemachine [options]>
+
+ Options:
+   --help            this help message
+   --verbose         displays additional messages
+   --pretend         just displays what would have been done
+
+=cut
diff --git a/rrsync b/rrsync
new file mode 100755
index 0000000..723e51b
--- /dev/null
+++ b/rrsync
@@ -0,0 +1,229 @@
+#!/usr/bin/perl -w
+# Based on rrsync of Joe Smith <js-cgi@inwap.com> and Wayne Davison <wayned@samba.org>
+use strict;
+
+use Socket;
+use Cwd 'abs_path';
+use File::Glob ':glob';
+use POSIX ":sys_wait_h";
+use POSIX qw(strftime);
+
+# You may configure these values to your liking.  See also the section
+# of options if you want to disable any options that rsync accepts.
+use constant RSYNC => '/usr/bin/rsync';
+use constant LOGFILE => '/var/log/rrsync.log';
+
+my $Usage = <<EOM;
+Use 'command="$0 [-ro] SUBDIR"'
+	in front of lines in $ENV{HOME}/.ssh/authorized_keys
+EOM
+
+our $ro = (@ARGV && $ARGV[0] eq '-ro') ? shift : '';	# -ro = Read-Only
+our $subdir = shift;
+die "$0: No subdirectory specified\n$Usage" unless defined $subdir;
+$subdir = abs_path($subdir);
+die "$0: Restricted directory does not exist!\n" if $subdir ne '/' && !-d $subdir;
+
+# The client uses "rsync -av -e ssh src/ server:dir/", and sshd on the server
+# executes this program when .ssh/authorized_keys has 'command="..."'.
+# For example:
+# command="rrsync logs/client" ssh-rsa AAAAB3NzaC1yc2EAAAABIwAAAIEAzGhEeNlPr...
+# command="rrsync -ro results" ssh-rsa AAAAB3NzaC1yc2EAAAABIwAAAIEAmkHG1WCjC...
+#
+# Format of the environment variables set by sshd:
+# SSH_ORIGINAL_COMMAND=rsync --server          -vlogDtpr --partial . ARG # push
+# SSH_ORIGINAL_COMMAND=rsync --server --sender -vlogDtpr --partial . ARGS # pull
+# SSH_CONNECTION=client_addr client_port server_port
+
+my $command = $ENV{SSH_ORIGINAL_COMMAND};
+#warn $command;
+die "$0: Not invoked via sshd\n$Usage"	unless defined $command;
+die "$0: SSH_ORIGINAL_COMMAND='$command' is not rsync\n" unless $command =~ s/^rsync\s+//;
+die "$0: --server option is not first\n" unless $command =~ /^--server\s/;
+our $am_sender = $command =~ /^--server\s+--sender\s/; # Restrictive on purpose!
+die "$0 -ro: sending to read-only server not allowed\n" if $ro && !$am_sender;
+
+### START of options data produced by the cull_options script. ###
+
+# These options are the only options that rsync might send to the server,
+# and only in the option format that the stock rsync produces.
+
+# To disable a short-named option, add its letter to this string:
+our $short_disabled = 's';
+
+our $short_no_arg = 'ACDEHIJKLORSWXbcdgklmnoprstuvxyz'; # DO NOT REMOVE ANY
+our $short_with_num = 'B'; # DO NOT REMOVE ANY
+
+# To disable a long-named option, change its value to a -1.  The values mean:
+# 0 = the option has no arg; 1 = the arg doesn't need any checking; 2 = only
+# check the arg when receiving; and 3 = always check the arg.
+our %long_opt = (
+  'append' => 0,
+  'backup-dir' => 2,
+  'bwlimit' => 1,
+  'checksum-seed' => 1,
+  'compare-dest' => 2,
+  'compress-level' => 1,
+  'copy-dest' => 2,
+  'copy-unsafe-links' => 0,
+  'daemon' => -1,
+  'debug' => 1,
+  'delay-updates' => 0,
+  'delete' => 0,
+  'delete-after' => 0,
+  'delete-before' => 0,
+  'delete-delay' => 0,
+  'delete-during' => 0,
+  'delete-excluded' => 0,
+  'delete-missing-args' => 0,
+  'existing' => 0,
+  'fake-super' => 0,
+  'files-from' => 3,
+  'force' => 0,
+  'from0' => 0,
+  'fuzzy' => 0,
+  'groupmap' => 1,
+  'iconv' => 1,
+  'ignore-errors' => 0,
+  'ignore-existing' => 0,
+  'ignore-missing-args' => 0,
+  'info' => 1,
+  'inplace' => 0,
+  'link-dest' => 2,
+  'list-only' => 0,
+  'log-file' => 3,
+  'log-format' => 1,
+  'max-delete' => 1,
+  'max-size' => 1,
+  'min-size' => 1,
+  'modify-window' => 1,
+  'new-compress' => 0,
+  'no-implied-dirs' => 0,
+  'no-r' => 0,
+  'no-relative' => 0,
+  'no-specials' => 0,
+  'numeric-ids' => 0,
+  'only-write-batch' => 1,
+  'partial' => 0,
+  'partial-dir' => 2,
+  'preallocate' => 0,
+  'remove-sent-files' => $ro ? -1 : 0,
+  'remove-source-files' => $ro ? -1 : 0,
+  'safe-links' => 0,
+  'sender' => 0,
+  'server' => 0,
+  'size-only' => 0,
+  'skip-compress' => 1,
+  'specials' => 0,
+  'stats' => 0,
+  'suffix' => 1,
+  'super' => 0,
+  'temp-dir' => 2,
+  'timeout' => 1,
+  'use-qsort' => 0,
+  'usermap' => 1,
+);
+
+### END of options data produced by the cull_options script. ###
+
+if ($short_disabled ne '') {
+    $short_no_arg =~ s/[$short_disabled]//go;
+    $short_with_num =~ s/[$short_disabled]//go;
+}
+$short_no_arg = "[$short_no_arg]" if length($short_no_arg) > 1;
+$short_with_num = "[$short_with_num]" if length($short_with_num) > 1;
+
+my $write_log = -f LOGFILE && open(LOG, '>>', LOGFILE);
+
+chdir($subdir) or die "$0: Unable to chdir to restricted dir: $!\n";
+
+my(@opts, @args);
+my $in_options = 1;
+my $last_opt = '';
+my $check_type;
+while ($command =~ /((?:[^\s\\]+|\\.[^\s\\]*)+)/g) {
+  $_ = $1;
+  if ($check_type) {
+    push(@opts, check_arg($last_opt, $_, $check_type));
+    $check_type = 0;
+  } elsif ($in_options) {
+    push(@opts, $_);
+    if ($_ eq '.') {
+      $in_options = 0;
+    } else {
+      die "$0: invalid option: '-'\n" if $_ eq '-';
+      next if /^-$short_no_arg*(e\d*\.\w*)?$/o || /^-$short_with_num\d+$/o;
+
+      my($opt,$arg) = /^--([^=]+)(?:=(.*))?$/;
+      my $disabled;
+      if (defined $opt) {
+				my $ct = $long_opt{$opt};
+				last unless defined $ct;
+				next if $ct == 0;
+				if ($ct > 0) {
+				  if (!defined $arg) {
+				    $check_type = $ct;
+				    $last_opt = $opt;
+				    next;
+				  }
+				  $arg = check_arg($opt, $arg, $ct);
+				  $opts[-1] =~ s/=.*/=$arg/;
+				  next;
+				}
+				$disabled = 1;
+				$opt = "--$opt";
+      } elsif ($short_disabled ne '') {
+				$disabled = /^-$short_no_arg*([$short_disabled])/o;
+				$opt = "-$1";
+      }
+
+      last unless $disabled; # Generate generic failure
+      die "$0: option $opt has been disabled on this server.\n";
+    }
+  } # else: do not take the target dir into account
+}
+die "$0: invalid rsync-command syntax or options\n" if $in_options;
+
+@args = ( ".current" );
+
+if ($write_log) {
+  my $host = $ENV{SSH_CONNECTION} || 'unknown';
+  $host =~ s/ .*//; # Keep only the client's IP addr
+  $host =~ s/^::ffff://;
+  $host = gethostbyaddr(inet_aton($host),AF_INET) || $host;
+  printf LOG "%s %-13s [%s]\n", (strftime ("%Y/%m/%d %H:%M:%S", localtime)), $host, "@opts @args";
+  close LOG;
+}
+
+my $pid = fork();
+if ($pid == 0) {
+  # Note: This assumes that the rsync protocol will not be maliciously hijacked.
+  exec(RSYNC, @opts, @args) or die "exec(rsync @opts @args) failed: $? $!";
+} elsif (not defined $pid) {
+  die "$0: cannot fork: $!\n";
+} # else: we are the father, so continue until the end of the script
+
+sub check_arg
+{
+  my($opt, $arg, $type) = @_;
+  $arg =~ s/\\(.)/$1/g;
+  if ($subdir ne '/' && ($type == 3 || ($type == 2 && !$am_sender))) {
+    $arg =~ s{//}{/}g;
+    die "Do not use .. in --$opt; anchor the path at the root of your restricted dir.\n"
+      if $arg =~ m{(^|/)\.\.(/|$)};
+    $arg =~ s{^/}{$subdir/};
+  }
+  $arg;
+}
+
+die "waitpid failed: $?\n"
+  if waitpid($pid, 0) < 0;
+my $child_ret = $? >> 8;
+if ($child_ret == 0) {
+	if (-d ".current") {
+		my $current_date = strftime "%Y-%m-%d %H.%M.%S", localtime;
+		rename ".current", $current_date;
+		unlink ".last";
+		symlink $current_date, ".last";
+  }
+} # else: do nothing. The next rsync will catch up !
diff --git a/sync-user-home b/sync-user-home
new file mode 100755
index 0000000..f1315da
--- /dev/null
+++ b/sync-user-home
@@ -0,0 +1,59 @@
+#!/bin/bash
+
+if [ $# -le 1 ]; then
+  ROOT="$HOME"
+else
+  ROOT="$2"
+fi
+
+. /usr/local/etc/sync.conf
+if [ $? -gt 0 ]; then
+  echo "No configuration could be found. Please write the configuration in /usr/local/etc/sync.conf !"
+  exit 1
+fi
+
+function try_lock() {
+  local file="$ROOT/.rsync-lock"
+  exec 200> $file
+  if [ $? -ne 0 ]; then
+    echo "Cannot create/open lock file: $file"
+    exit 1
+  fi
+  flock -n 200
+}
+
+case $1 in
+sync)
+  if ! try_lock; then
+    echo "Synchronisation is already in progress. Aborting right now !" >&2
+    exit 1
+  fi
+  echo "Starting synchronisation..."
+  rsync -e "ssh -i $HOME/.ssh/id_rsa_backup" --filter "merge $ROOT/.rsync-user-filter" $RSYNC_OPTS $ROOT/ $USER@$REMOTE_HOSTNAME:$ROOT
+  ret=$?
+  if [ $ret -gt 0 ]; then
+    exit $ret
+  else
+    touch "$ROOT/.rsync-timestamp"
+  fi
+;;
+status)
+  if try_lock; then
+    echo "Syncronization service for path $ROOT: STOPPED"
+  else
+    echo "Syncronization service for path $ROOT: RUNNING"
+  fi
+;;
+pending)
+  rsync -e "ssh -i $HOME/.ssh/id_rsa_backup" --filter "merge $ROOT/.rsync-user-filter" $RSYNC_OPTS --dry-run --stats $ROOT/ $USER@$REMOTE_HOSTNAME:$ROOT |sed -r 's/^Total transferred file size: ([0-9,]+) bytes.*/\1/; t clean; d; :clean; s/,//g'
+;;
+last)
+  stat -c %Y $ROOT/.rsync-timestamp
+;;
+*)
+  echo "$0 {sync|status|pending|last}"
+  exit 1
+;;
+esac
+
+exit 0